My colleague Amer Yassine recently finished posted his amazing 40 video tutorial on skinning and rigging for games on the 3ds Max learning channel on YouTube. The process of adjusting vertex weights during skinning is very repetitive so he asked me to help him come up with a MAXScript tool to help ease the process. MAXScript mouse tools are explained here in the MAXScript documentation.

macroScript QuickSkinVertexWeight category:"Custom Skin Tools"
tooltip:"Quick Vertex Weight Tool"
(
    tool AssignSkinVertexWeightTool
    (
        local original
        fn setweight wt = (
            if (wt < 0) then wt = 0
            if (wt > 1.0) then wt = 1.0
            skinOps.setWeight $.modifiers[#Skin] wt
            $.modifiers[#Skin].effect = wt
        )          
        on mousePoint clickno do (            
            if clickno > 1 then return #stop     
            original = $.modifiers[#Skin].effect
        )
        on mouseAbort clickno do (
            setweight original
        )
        on mouseMove clickno do (
            newval = (original + (gridDist.x  * 0.01))
            setweight newval
        )
    )
    startTool AssignSkinVertexWeightTool prompt:"Set Vertex Weight"
)
 

Here is the video where Amer first introduces the tool and explains how it works, enjoy!